HOW TO：發行具有指定地區的專案

How to: Publish a Project That Has a Specific Locale

To create the publishing macro

1. To open the Macro Explorer, on the Tools menu, point to Macros, and then click Macro Explorer.

2. Create a new macro module. In the Macro Explorer, select MyMacros. On the Tools menu, point to Macros, and then click New Macro Module. Name the module PublishSpecificCulture.

3. In the Macro Explorer, expand the MyMacros node, and then open the PublishAllProjects module by double-clicking it (or, from the Tools menu, point to Macros, and then click Macros IDE).

4. In the Macros IDE, add the following code to the module, after the Import statements:

   VB

   Module PublishSpecificCulture
       Sub PublishProjectFirstProjectWithEnLocale()
           ' Note: You should publish projects by using the IDE at least once
           ' before you use this macro. Items such as the certficate and the 
           ' security zone must be set.
           Dim localeString As String = "en"
   
           ' Get first project.
           Dim proj As Project = DTE.Solution.Projects.Item(1)
           Dim publishProperties As Object = proj.Properties.Item("Publish").Value
   
           ' GenerateManifests and SignManifests must always be set to
           ' True for publishing to work. 
           proj.Properties.Item("GenerateManifests").Value = True
           proj.Properties.Item("SignManifests").Value = True
   
           'Set the publish language.
           'This will set the deployment language and pick up all 
           ' en resource dlls:
           Dim originalTargetCulture As String = _
               publishProperties.Item("TargetCulture").Value
           publishProperties.Item("TargetCulture").Value = localeString
   
           'Append 'en' to end of publish, install, and update URLs if needed:
           Dim originalPublishUrl As String = _
               publishProperties.Item("PublishUrl").Value
           Dim originalInstallUrl As String = _
               publishProperties.Item("InstallUrl").Value
           Dim originalUpdateUrl As String = _
               publishProperties.Item("UpdateUrl").Value
           publishProperties.Item("PublishUrl").Value = _
               AppendStringToUrl(localeString, New Uri(originalPublishUrl))
           If originalInstallUrl <> String.Empty Then
               publishProperties.Item("InstallUrl").Value = _
                   AppendStringToUrl(localeString, New Uri(originalInstallUrl))
           End If
           If originalUpdateUrl <> String.Empty Then
               publishProperties.Item("UpdateUrl").Value = _
                   AppendStringToUrl(localeString, New Uri(originalUpdateUrl))
           End If
           proj.Save()
   
           Dim slnbld2 As SolutionBuild2 = _
               CType(DTE.Solution.SolutionBuild, SolutionBuild2)
           slnbld2.Clean(True)
   
           slnbld2.BuildProject( _
           proj.ConfigurationManager.ActiveConfiguration.ConfigurationName, _
           proj.UniqueName, True)
   
           ' Only publish if build is successful.
           If slnbld2.LastBuildInfo <> 0 Then
               MsgBox("Build failed for " & proj.UniqueName)
           Else
               slnbld2.PublishProject( _
               proj.ConfigurationManager.ActiveConfiguration.ConfigurationName, _
               proj.UniqueName, True)
               If slnbld2.LastPublishInfo = 0 Then
                   MsgBox("Publish succeeded for " & proj.UniqueName _
                   & vbCrLf & "." _
                   & " Publish Language was '" & localeString & "'.")
               Else
                   MsgBox("Publish failed for " & proj.UniqueName)
               End If
           End If
   
           ' Return URLs and target culture to their previous state.
           publishProperties.Item("PublishUrl").Value = originalPublishUrl
           publishProperties.Item("InstallUrl").Value = originalInstallUrl
           publishProperties.Item("UpdateUrl").Value = originalUpdateUrl
           publishProperties.Item("TargetCulture").Value = originalTargetCulture
           proj.Save()
       End Sub
   
       Private Function AppendStringToUrl(ByVal str As String, _
       ByVal baseUri As Uri) As String
           Dim returnValue As String = baseUri.OriginalString
           If baseUri.IsFile OrElse baseUri.IsUnc Then
               returnValue = IO.Path.Combine(baseUri.OriginalString, str)
           Else
               If Not baseUri.ToString.EndsWith("/") Then
                   returnValue = baseUri.OriginalString & "/" & str
               Else
                   returnValue = baseUri.OriginalString & str
               End If
           End If
           Return returnValue
       End Function
   End Module
   

5. Close the Macros IDE. The focus will return to Visual Studio.